Aminet 15/Aminet 15 - Nov 1996.iso/Aminet/comm/mmgr/MM_FbMRMv12.lha/MM/Rexx/MM_FbMReq.rexx

OS/2 REXX Batch file | 1996-09-01 | 35KB | 914 lines

/*

    File-by-Mail-Request Server

    © 1996 by Sebastian Bleikamp.
    All rights reserved.

    version 1.2


--------\
History: ----------------------------------------------------------------
--------/

SINCE v 0.7:

    ->  !!!! New index format: !!!!
        Name|Type|Path|Level|Desc
        (Before: Type|Name| ... )

    ->  Functions ok:
        HELP
        LIST
        SCAN
        SEARCH
        GET

    ->  EMail Support !!!!!
    ->  Passwd Support !!!


SINCE v 0.8:

    -> Replace Patterns !!!
       !! Other filenames for text files !!


SINCE v 0.9:

    -> Much more replace patterns !!
       Now all message infos are avaible !

    -> UUencode: MAXSIZE added !!
    -> Textfile: MAXSIZE added !!


SINCE v 0.10:

    -> Filelist will be splittet, too !


SINCE v 0.11:

    -> some more replace patterns ...

    -> now there are two different values for text and binary max.
       message size.

    -> Wrong-Password function improved: Message will be sent back.

    -> Maany bugfixes.


SINCE v 0.12:

    -> Now with a configfile !!!
    -> Configureable subjects.


SINCE v 1.0(a):

    -> new option: #DONEFLAGS
       you can specify the flags a message gets after processing.

    -> new index format: group|name|...

    -> added group features ...

    -> AmigaDOS Patterns can be used for searching ...

    -> new %LIST command: %LIST <group-pattern>


SINCE v 1.1:

    -> Filesize was added to the index.
       Group|Name|Type|Path|Size|Level|Desc
       {FSIZE} pattern added.

    -> added .readme files ...
    -> now a textfile (.readme) will be send before the file.

    -> configureable flags for message searching ...

    -> now with %HOLD function !

---------------------------------------------------------------------------
*/


address 'MAILMANAGER'


call Init()
call Read_Index()

call Get_The_List()
call Check_Passwords()

call Do_Requests()


call ByeBye(0,)
exit 0



/*---------------------------------------------------------------------------*\
|*  Standart Functions:                                                      *|
\*---------------------------------------------------------------------------*/


Init:
    system.     = 0
    ToDoList.  = 0
    IndexStem. = 0
    FileStem.  = 0

    call LogInit()
    call LogHeader()

    system.configfile           = 'MM:Config/MM_FbMRM.cfg'
    call Read_Config()

return


ByeBye: procedure expose system.
    parse arg ecode ',;' estring
    if estring~='' then do
        say estring
        call Log(estring',;2')
    end
    call LogFooter()
    call LogQuit()
    exit ecode
return


/* Log-Funktions: ---------------------------------------------------------*/

LogInit:
        system.prg.name         = 'MM_FbMReqManager'
        system.prg.ver          = '1.2'
        system.prg.id           = system.prg.name 'v'system.prg.ver
        system.prg.stdlev       = 3
        system.mm.logpre        = getclip('MM_LogPre')
        system.prg.logpre       = system.mm.logpre'|'
        call                    setclip('MM_LogPre', system.prg.logpre)
return

LogQuit:
        arg rc
        call setclip('MM_LogPre', system.mm.logpre)
        MM_CloseLog
exit rc

LogHeader: PROCEDURE Expose system.
        call Log(',;2,;/')
        call Log('***' system.prg.id 'started ***,;2,;+')
        call Log(',;2')
return

LogFooter: procedure Expose system.
        call Log(',;2')
        call Log('***' system.prg.id 'ended ***,;2,;+')
        call Log(',;2,;\')
return

Log: procedure Expose system.
        parse arg text ',;' level ',;' pre
        tmp         = word('PRG MM', (pre~='')+1)
        text        = system.tmp.logpre || pre' 'text
        if level='' then level=system.prg.stdlev
        MM_WriteLog 'text' level
return




/*---------------------------------------------------------------------------*\
|*  Program Functions:                                                       *|
\*---------------------------------------------------------------------------*/


Get_The_List:  procedure expose system. ToDoList.
    call Log('Searching for new messages ...,;,;+')
    ToDoList.count=0
    MM_GetAreas 'AreaList' 'MAIL'
    do area = 0 to AreaList.count-1
        MM_SearchMsgs AreaList.area 'MsgList' '#?' '#?' '#?' system.cfg.sflags
        do msg=0 to MsgList.count-1
            MM_ReadMsg AreaList.area MsgList.msg 'MsgStem'
            if (rc~=0) then call ByeBye('100,;***Error: Unable to read message !')
            if (find(upper(system.servername),upper(MsgStem.TO))~=0) then do
                i = ToDoList.count
                ToDoList.i.MsgArea          = AreaList.area
                ToDoList.i.MsgNum           = MsgList.msg
                ToDoList.i.MsgFrom          = MsgStem.FROM
                ToDoList.i.MsgFromAddr      = MsgStem.FROMADDR
                ToDoList.i.MsgSubj          = MsgStem.SUBJ
                ToDoList.i.Level            = system.cfg.stdlevel
                ToDoList.i.EMail            = ''
                do kludge=0 to MsgStem.HEAD.count-1
                    if (pos('REPLYADDR',upper(word(MsgStem.HEAD.kludge,1)))~=0) then do
                        parse var MsgStem.HEAD.kludge pre ' ' ToDoList.i.EMail
                    end
                end
                ToDoList.count = i+1
            end
        end
    end
    call Log('... done. Found '||toDoList.count||' message(s) to do.')
return




Do_Requests: procedure expose system. IndexStem. FileStem. ToDoList.
    do todo=0 to ToDoList.count-1
        if (TodoList.todo.email~='') then who=ToDoList.todo.email||' ('ToDoList.todo.MsgFrom||')'
        else who=ToDoList.todo.MsgFrom||' ('ToDoList.todo.MsgFromAddr||')'
        call Log()
        call Log('Message from 'who', level '||ToDoList.todo.Level||'.,;,;+')
        MM_ReadMsg ToDoList.todo.MsgArea ToDoList.todo.MsgNum 'MsgStem'
        if (rc~=0) then call ByeBye('100,;***Error: Unable to read message !')

        /* create info: */
        system.info.Area        = ToDoList.todo.MsgArea
        system.info.Number      = ToDoList.todo.MsgNum
        system.info.From        = ToDoList.todo.MsgFrom
        system.info.FromAddr    = ToDoList.todo.MsgFromAddr
        system.info.To          = MsgStem.TO
        system.info.ToAddr      = MsgStem.TOADDR
        system.info.Subject     = MsgStem.SUBJ
        system.info.Date        = MsgStem.DATE
        system.info.Flags       = MsgStem.FLAGS
        system.info.Level       = ToDoList.todo.Level
        system.info.EMail       = ToDoList.todo.EMail
        system.info.fromwho         = who

        do textcount=0 to MsgStem.TEXT.count-1
            system.info.prc.fgroup = ''
            system.info.prc.fname  = ''
            system.info.prc.ftype  = ''
            system.info.prc.fpath  = ''
            system.info.prc.fsize  = 0
            system.info.prc.flevel = -1
            system.info.prc.fdesc  = ''
            system.info.prc.part      = 0
            system.info.prc.maxpart   = 0
            parse var MsgStem.TEXT.textcount pre '%' keyword ' ' arguments
            select
                when (pre~='')                  then NOP
                when (upper(keyword)='HELP')    then call Send_Helpfile(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail)
                when (upper(keyword)='LIST')    then call Send_Filelist(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'arguments)
                when (upper(keyword)='GET')     then call Send_File(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'word(arguments,1))
                when (upper(keyword)='SCAN')    then call Send_Scan(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'word(arguments,1))
                when (upper(keyword)='README')  then call Send_ReadMe(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'word(arguments,1))
                when (upper(keyword)='SEARCH')  then call Send_Search(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'word(arguments,1))
                when (upper(keyword)='HOLD')    then call Send_Hold(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'ToDoList.todo.Level',;'word(arguments,1))
                otherwise NOP
            end
        end
        MM_EditMsgFlags ToDoList.todo.MsgArea ToDoList.todo.MsgNum 'system.cfg.doneflags'
    end
return





Send_Helpfile: procedure expose system.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail
    call Log('-> Sending Helpfile.')
    call Build_MessageBody(system.text.helpfile||',;'||system.tempfile)
    call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.helpfile)
    MM_DeleteFile system.tempfile
return





Send_Filelist: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' searchgroup
    system.info.prc.flevel = level
    if (searchgroup='') then searchgroup = '#?'
    thisgroup = ''
    DummyStem.count=0
    do i=0 to IndexStem.count-1
        if ((IndexStem.i.flevel<=level)&(Check_Pattern(IndexStem.i.fgroup||',;'||searchgroup))) then do
            if (IndexStem.i.fgroup~=thisgroup) then do
                thisgroup = IndexStem.i.fgroup
                j=DummyStem.count
                DummyStem.j = ''; j=j+1
                DummyStem.j = 'Group: '||thisgroup; j=j+1
                DummyStem.j = '------';j=j+1
                DummyStem.count = j
            end
            j = DummyStem.count
            DummyStem.j = '  'IndexStem.i.fname
            do k=0 to (26-(length(DummyStem.j)+length(IndexStem.i.fsize)))
                DummyStem.j=DummyStem.j||' '
            end
            DummyStem.j=DummyStem.j||' '||IndexStem.i.fsize||'  '||IndexStem.i.fdesc
            DummyStem.count = j+1
        end
    end

    i=0; j=0
    do while (i<DummyStem.count)
        anz=0; TextStem.j.count=0
        do while ((anz<system.cfg.txtmaxsize)&(i<DummyStem.count))
            anz = anz + length(DummyStem.i)
            MM_AddToStem 'TextStem.'||j 'DummyStem.'||i
            i=i+1
        end
        j=j+1
    end
    TextStem.count=j
    call Log('-> Sending filelist  ( 'TextStem.count' message(s)).')
    system.info.prc.maxpart = TextStem.count
    do i=0 to TextStem.count-1
        system.info.prc.part = (i+1)
        MM_WriteStem system.tempfile 'TextStem.'||i
        if (rc~=0) then ByeBye('100,;***Error: Unable to write tempfile !!')
        call Build_MessageBody(system.text.filelist||',;'||system.tempfile||',;'||system.tempfile)
        call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.filelist)
        MM_DeleteFile system.tempfile
    end

return




Send_File: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' filename
    system.info.prc.flevel = level
    call Scan_Index(filename',;'level)
    call Check_FileStem_Dupes()
    system.info.prc.fname  = filename
    if (FileStem.count=0) then call Send_FileNotFound(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filename)
    else do
        do i=0 to Filestem.count-1
            system.info.prc.fgroup = FileStem.i.fgroup
            system.info.prc.ftype  = FileStem.i.ftype
            system.info.prc.fpath  = FileStem.i.fpath
            system.info.prc.fsize  = FileStem.i.fsize
            system.info.prc.flevel = FileStem.i.flevel
            system.info.prc.fdesc  = FileStem.i.fdesc
            select
                when (upper(FileStem.i.ftype)='FILE') then call Send_BFile(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filename',;'FileStem.i.fpath)
                when (upper(FileStem.i.ftype)='TEXT') then call Send_TFile(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filename',;'FileStem.i.fpath)
                otherwise ByeBye('200,;***Error: Unknown file type !!')
            end
        end
    end
return





Send_Scan: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' filename
    call Search_Index(filename',;'level)
    DummyStem.count=0
    do i=0 to FileStem.count-1
        j=DummyStem.count
        DummyStem.j = FileStem.i.fname||' '

        do k=0 to (26-(length(FileStem.i.fname)+length(FileStem.j.fsize)))
            DummyStem.j = DummyStem.j||' '
        end
        DummyStem.j = DummyStem.j||FileStem.i.fsize||' '||FileStem.i.fgroup||' '
        do k=0 to (10-length(FileStem.i.fgroup))
            DummyStem.j = DummyStem.j||' '
        end
        DummyStem.j = DummyStem.j||FileStem.i.fdesc
        DummyStem.count = j+1
    end
    MM_WriteStem system.tempfile 'DummyStem'
    if (rc~=0) then ByeBye('100,;***Error: Unable to write tempfile !!')
    system.info.prc.fname = filename
    system.info.prc.flevel = level
    call Build_MessageBody(system.text.search||',;'||system.tempfile||',;'||system.tempfile)
    call LOG('-> Scanning for '||filename||'.')
    call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.search)
    MM_DeleteFile system.tempfile
return



Send_ReadMe: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' filename
    call Search_Index(filename',;'level)

    call LOG('-> Sending readmes for '||filename||'.')
    do i=0 to FileStem.count-1
        system.info.prc.fgroup = FileStem.i.fgroup
        system.info.prc.fname  = FileStem.i.fname
        system.info.prc.ftype  = FileStem.i.ftype
        system.info.prc.fpath  = FileStem.i.fpath
        system.info.prc.fsize  = FileStem.i.fsize
        system.info.prc.flevel = FileStem.i.flevel
        system.info.prc.fdesc  = FileStem.i.fdesc
        system.info.prc.maxpart = 0
        call Send_The_ReadMe(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'FileStem.i.fpath)
    end
return





Send_Search: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' filename
    call Search_Index(filename',;'level)
    call Check_FileStem_Dupes()
    DummyStem.count=0
    do i=0 to FileStem.count-1
        call Send_File(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'level',;'FileStem.i.fname)
    end
return



Send_Hold: procedure expose system. IndexStem.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' level ',;' filename
    if (level>=system.cfg.holdlevel) then do
        call Search_Index(filename',;'level)
        call Check_FileStem_Dupes()
        if (FileStem.count=0) then call Send_FileNotFound(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filename)
        do i=0 to FileStem.count-1
            system.info.prc.fgroup = FileStem.i.fgroup
            system.info.prc.fname  = FileStem.i.fname
            system.info.prc.ftype  = FileStem.i.ftype
            system.info.prc.fpath  = FileStem.i.fpath
            system.info.prc.fsize  = FileStem.i.fsize
            system.info.prc.flevel = FileStem.i.flevel
            system.info.prc.fdesc  = FileStem.i.fdesc
            system.info.prc.maxpart = 0
            readme = Get_ReadMe( FileStem.i.fpath )
            system.info.prc.part = 0
            call Build_MessageBody(system.text.hold||',;'||system.tempfile||',;'||readme)
            call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.hold)
            MM_DeleteFile system.tempfile
            MM_AddToFlow FileStem.i.fpath To_Addr 'HOLD'
        end
    end
    else do
        call Send_FileNotFound(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filename)
    end
return





/*---------------------------------------------------------------------------*\
|*  Support Functions:                                                       *|
\*---------------------------------------------------------------------------*/


Send_BFile: procedure expose system.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' filename ',;' filepath
    /* execute uuencode: */
    com = system.uuencode
    com = Replace_String(com||',;'||'{INFILE}'||',;'||filepath)
    com = Replace_String(com||',;'||'{OUTFILE}'||',;'||system.tempfile||'.')
    com = Replace_String(com||',;'||'{MAXSIZE}'||',;'||system.cfg.binmaxsize)
    address command com
    /* Count files: */
    check=1; count=-1
    do while (check~=0)
        count=count+1; drop check
        MM_CRCFile system.tempfile||'.'||(count+1) check
    end
    system.info.prc.maxpart = count
    call Log('-> Sending binary file '||filename||' ('filepath', 'count' message(s)).')
    call Send_The_ReadMe(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filepath)
    do i=1 to count
        system.info.prc.part = i
        call Build_MessageBody(system.text.sendfile||',;'||system.tempfile||'.'||i||',;'||system.tempfile||'.'||i)
        call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile||'.'||i||',;'system.subj.sendfile)
        MM_DeleteFile system.tempfile||'.'||i
    end

return



Send_TFile: procedure expose system.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' filename ',;' filepath
    MM_ReadStem filepath 'DummyStem'
    i=0; j=0
    do while (i<DummyStem.count)
        anz=0; TextStem.j.count=0
        do while ((anz<system.cfg.txtmaxsize)&(i<DummyStem.count))
            anz = anz + length(DummyStem.i)
            MM_AddToStem 'TextStem.'||j 'DummyStem.'||i
            i=i+1
        end
        j=j+1
    end
    TextStem.count=j

    call Log('-> Sending textfile '||filename' ('filepath', 'TextStem.count' message(s)).')
    system.info.prc.maxpart = TextStem.count
    call Send_The_ReadMe(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'filepath)

    do i=0 to TextStem.count-1
        system.info.prc.part = (i+1)
        MM_WriteStem system.tempfile 'TextStem.'||i
        if (rc~=0) then ByeBye('100,;***Error: Unable to write tempfile !!')
        call Build_MessageBody(system.text.sendtext||',;'||system.tempfile||',;'||system.tempfile)
        call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile||',;'system.subj.sendtext)
        MM_DeleteFile system.tempfile
    end

return



Send_FileNotFound: procedure expose system.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' filename
    system.info.prc.fname = filename
    call Log('-> File not found: '||filename||'.')
    call Build_MessageBody(system.text.filenotfound||',;'||system.tempfile)
    call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.filenotfound)
    MM_DeleteFile system.tempfile
return



Send_The_ReadMe: procedure expose system.
    parse arg To_Area ',;' To_Name ',;' To_Addr ',;' To_EMail ',;' filename
    readme = Get_ReadMe( filename )
    system.info.prc.part = 0
    call Build_MessageBody(system.text.sendreadme||',;'||system.tempfile||',;'||readme)
    call Send_Msg(To_Area',;'To_Name',;'To_Addr',;'To_EMail',;'system.tempfile',;'system.subj.sendreadme)
    MM_DeleteFile system.tempfile
return



Check_Passwords: procedure expose system. ToDoList.
    call Log()
    call Log('Password check.,;,;+')
    MM_ReadStem system.passwdfile 'DummyStem'
    PasswdStem.count=0
    do i=0 to DummyStem.count-1
        parse var DummyStem.i one '|' two '|' three
        if (one~='') then do
            x=PasswdStem.count
            PasswdStem.x.name  = one
            PasswdStem.x.pass  = two
            PasswdStem.x.level = three
            PasswdStem.count = x+1
        end
    end
    do todo=0 to ToDoList.count-1
        if (TodoList.todo.email~='') then who=ToDoList.todo.email||' ('ToDoList.todo.MsgFrom||')'
        else who=ToDoList.todo.MsgFrom||' ('ToDoList.todo.MsgFromAddr||')'
        if (ToDoList.todo.MsgSubj~='') then do
            checked=0
            do i=0 to PasswdStem.count-1
                if ((upper(ToDoList.todo.MsgFrom)=upper(PasswdStem.i.name))&(upper(ToDoList.todo.MsgSubj)=upper(PasswdStem.i.pass))) then do
                    checked=1
                    ToDoList.todo.Level = PasswdStem.i.level
                     i = PasswdStem.count
                end
            end
            if (checked=0) then do
                MM_ReadMsg ToDoList.todo.MsgArea ToDoList.todo.MsgNum 'MsgStem'
                if (rc~=0) then call ByeBye('100,;***Error: Unable to read message !')
                system.info.Area        = ToDoList.todo.MsgArea
                system.info.Number      = ToDoList.todo.MsgNum
                system.info.From        = ToDoList.todo.MsgFrom
                system.info.FromAddr    = ToDoList.todo.MsgFromAddr
                system.info.To          = MsgStem.TO
                system.info.ToAddr      = MsgStem.TOADDR
                system.info.Subject     = MsgStem.SUBJ
                system.info.Date        = MsgStem.DATE
                system.info.Flags       = MsgStem.FLAGS
                system.info.Level       = ToDoList.todo.Level
                system.info.EMail       = ToDoList.todo.EMail
                system.info.fromwho         = who
                MM_WriteStem system.tempfile 'MsgStem.TEXT'
                call Log('-> !!! WRONG PASSWORD for '||who||' !!!! (PW: "'||ToDoList.todo.MsgSubj||'"),;2,;!')
                call Build_MessageBody(system.text.wrongpass||',;'||system.tempfile||',;'||system.tempfile)
                call Send_Msg(ToDoList.todo.MsgArea',;'ToDoList.todo.MsgFrom',;'ToDoList.todo.MsgFromAddr',;'ToDoList.todo.EMail',;'system.tempfile',;'system.subj.wrongpass)
                MM_DeleteFile system.tempfile
                ToDoList.todo.Level = -1
            end
            else call Log('-> User '||who||' identified. (Level '||ToDoList.todo.Level||'.)')
        end
    end
return




/*---------------------------------------------------------------------------*\
|*  Index   Functions:                                                       *|
\*---------------------------------------------------------------------------*/


Read_Index: procedure expose system.indexfile IndexStem.
    IndexStem.count = 0
    MM_ReadStem system.indexfile 'DummyStem'
    MM_SortStem 'DummyStem'
    do i=0 to DummyStem.count-1
        parse var DummyStem.i group '|' name '|' type '|' path '|' size '|' level '|' desc
        if (group~='') then do
            j = IndexStem.count
            IndexStem.j.fgroup  = group
            IndexStem.j.ftype   = type
            IndexStem.j.fname   = name
            IndexStem.j.fpath   = path
            IndexStem.j.fsize   = size
            IndexStem.j.flevel  = level
            IndexStem.j.fdesc   = desc
            IndexStem.count = IndexStem.count+1
        end
    end
return


Scan_Index: procedure expose IndexStem. FileStem.
    parse arg pattern ',;' level
    FileStem.count=0
    do i=0 to IndexStem.count
        if ((upper(pattern)=upper(IndexStem.i.fname))&(IndexStem.i.flevel<=level)) then do
            j = FileStem.count
            FileStem.j.fgroup = IndexStem.i.fgroup
            FileStem.j.ftype  = IndexStem.i.ftype
            FileStem.j.fname  = IndexStem.i.fname
            FileStem.j.fpath  = IndexStem.i.fpath
            FileStem.j.fsize  = IndexStem.i.fsize
            FileStem.j.flevel = IndexStem.i.flevel
            FileStem.j.fdesc  = IndexStem.i.fdesc
            FileStem.count = j+1
        end
    end
return


Check_Pattern: procedure
    parse arg In.0 ',;' pattern
    In.count=1; Out.count=0
    pattern = '"'||pattern||'"'
    MM_SearchInStem 'In' 'Out' pattern 'NUM'
return Out.count


Search_Index: procedure expose IndexStem. FileStem.
    parse arg pattern ',;' level
    FileStem.count=0
    do i=0 to IndexStem.count
        if (((Check_Pattern(IndexStem.i.fname||',;'||pattern)~=0)|(Check_Pattern(IndexStem.i.fdesc||',;'||pattern)~=0))&(IndexStem.i.flevel<=level)) then do
            j = FileStem.count
            FileStem.j.fgroup = IndexStem.i.fgroup
            FileStem.j.ftype  = IndexStem.i.ftype
            FileStem.j.fname  = IndexStem.i.fname
            FileStem.j.fpath  = IndexStem.i.fpath
            FileStem.j.fsize  = IndexStem.i.fsize
            FileStem.j.flevel = IndexStem.i.flevel
            FileStem.j.fdesc  = IndexStem.i.fdesc
            FileStem.count = j+1
        end
    end
return




/*---------------------------------------------------------------------------*\
|*  Other Functions:                                                         *|
\*---------------------------------------------------------------------------*/



Check_FileStem_Dupes: procedure expose FileStem.
    do i=0 to FileStem.count-2
        do j=(i+1) to FileStem.count-1
            if  ((upper(FileStem.i.fpath)=upper(FileStem.j.fpath))&(upper(FileStem.i.ftype)=upper(FileStem.j.ftype))) then do
                do k=j to FileStem.count-2
                    l = k+1
                    FileStem.k.ftype  = FileStem.l.ftype
                    FileStem.k.fname  = FileStem.l.fname
                    FileStem.k.fpath  = FileStem.l.fpath
                    FileStem.k.flevel = FileStem.l.flevel
                    FileStem.k.fdesc  = FileStem.l.fdesc
                end
                k=FileStem.count-1
                FileStem.k.fpath=''
                FileStem.count = k
                j=j-1
            end
        end
    end
return





/*---------------------------------------------------------------------------*\
|*  Replace & Send Functions :                                               *|
\*---------------------------------------------------------------------------*/


Send_Msg: procedure expose system.
    parse arg inarea ',;' to_name ',;' to_addr ',;' to_email ',;' iofile ',;' subject
    subject = Replace_My_Patterns(subject)
    if (to_email~='') then do
        TextStem.count=0
        TextStem.0 = 'To: '||to_email
        Textstem.1 = ''
        TextStem.count = 2
        MM_ReadStem iofile 'TextStem' 'APPEND'
        if (rc~=0) then ByeBye('100,;***Error: Unable to read iofile !!')
        MM_WriteStem system.tempfile||',send' 'TextStem'
        if (rc~=0) then ByeBye('100,;***Error: Unable to write tempfile !!')
        NewMsgStem.FILE = system.tempfile||',send'
    end
    else do
        NewMsgStem.FILE = iofile
    end
    NewMsgStem.FROM     = WORD(system.servername,1)
    NewMsgStem.FROMADDR = ''
    NewMsgStem.TO       = to_name
    NewMsgStem.TOADDR   = to_addr
    NewMsgStem.SUBJ     = subject
    NewMsgStem.FLAGS    = system.cfg.flags
    NewMsgStem.TEAR     = '" & FbMRManager"'
    MM_WriteMsg inarea 'NewMsgStem'
    if (rc~=0) then ByeBye('100,;***Error: Unable to send message !!')
    if (to_email~='') then do
        MM_DeleteFile system.tempfile||',send'
        if (rc~=0) then ByeBye('100,;***Error: Unable to delete tempfile !!')
    end
return




Replace_String: procedure
    parse arg string ',;' rep ',;' by
    do while (pos(rep,string)~=0)
        interpret "parse var string pre '"rep"' post"
        string = pre||by||post
    end
return string




Replace_My_Patterns: procedure expose system.

    parse arg string

    string = Replace_String(string||',;'|| '{SERVER}'   ||',;'||    word(system.servername,1)   )
    string = Replace_String(string||',;'|| '{SYSOP}'    ||',;'||    system.sysopname            )

    string = Replace_String(string||',;'|| '{PRGID}'    ||',;'||    system.prg.id               )
    string = Replace_String(string||',;'|| '{PRGNAME}'  ||',;'||    system.prg.name             )
    string = Replace_String(string||',;'|| '{PRGVER}'   ||',;'||    system.prg.ver              )

    string = Replace_String(string||',;'|| '{FROM}'     ||',;'||    system.info.From            )
    string = Replace_String(string||',;'|| '{FROMNICK}' ||',;'||    word(system.info.From,1)    )
    string = Replace_String(string||',;'|| '{FROMADDR}' ||',;'||    system.info.FromAddr        )
    string = Replace_String(string||',;'|| '{FROMWHO}'  ||',;'||    system.info.fromwho             )
    string = Replace_String(string||',;'|| '{EMAIL}'    ||',;'||    system.info.EMail           )
    string = Replace_String(string||',;'|| '{LEVEL}'    ||',;'||    system.info.Level           )

    string = Replace_String(string||',;'|| '{TO}'       ||',;'||    system.info.To              )
    string = Replace_String(string||',;'|| '{TOADDR}'   ||',;'||    system.info.ToAddr          )

    string = Replace_String(string||',;'|| '{MSGSUBJ}'  ||',;'||    system.info.Subject         )
    string = Replace_String(string||',;'|| '{MSGDATE}'  ||',;'||    system.info.Date            )
    string = Replace_String(string||',;'|| '{MSGFLAGS}' ||',;'||    system.info.Flags           )
    string = Replace_String(string||',;'|| '{MSGAREA}'  ||',;'||    system.info.Area            )
    string = Replace_String(string||',;'|| '{MSGNUM}'   ||',;'||    system.info.Number          )

    string = Replace_String(string||',;'|| '{FGROUP}'   ||',;'||    system.info.prc.fgroup      )
    string = Replace_String(string||',;'|| '{FNAME}'    ||',;'||    system.info.prc.fname       )
    string = Replace_String(string||',;'|| '{FTYPE}'    ||',;'||    system.info.prc.ftype       )
    string = Replace_String(string||',;'|| '{FPATH}'    ||',;'||    system.info.prc.fpath       )
    string = Replace_String(string||',;'|| '{FSIZE}'    ||',;'||    system.info.prc.fsize       )
    string = Replace_String(string||',;'|| '{FLEVEL}'   ||',;'||    system.info.prc.flevel      )
    string = Replace_String(string||',;'|| '{FDESC}'    ||',;'||    system.info.prc.fdesc       )
    string = Replace_String(string||',;'|| '{FPART}'    ||',;'||    system.info.prc.part        )
    string = Replace_String(string||',;'|| '{FMAXPART}' ||',;'||    system.info.prc.maxpart     )

return string



Build_MessageBody: procedure expose system.
    parse arg infile ',;' outfile ',;' textfile

    Text.         = 0
    Text.count    = 0
    NewText.      = 0
    NewText.count = 0

    MM_ReadStem infile 'Text'
    if (rc~=0) then ByeBye('100,;***Error: Unable to read inputfile "'||infile||'" !!')
    do i=0 to Text.count-1
        Text.i = Replace_My_Patterns(Text.i)
    end
    do i=0 to Text.count-1
        if (word(Text.i,1)='{TEXT}') then do
            if (textfile~='') then do
                MM_ReadStem textfile 'NewText' 'APPEND'
                if (rc~=0) then ByeBye('100,;***Error: Unable to read textfile "'||textfile||'" !!')
            end
        end
        else do
            MM_AddToStem 'NewText' 'Text.'i
        end
    end
    MM_WriteStem outfile 'NewText'
    if (rc~=0) then ByeBye('100,;***Error: Unable to write outputfile "'||outfile||'" !!')
return


Strip_Extension: procedure
    parse arg string
return Left( string, (LastPos( '.', string) - 1) )

Get_ReadMe: procedure
    parse arg string
    string = Strip_Extension(string)||'.readme'
    if (exists(string)=0) then string = ''
return string



/*-----------------------------------------------------------------------*/
/* Read Config:                                                          */
/*-----------------------------------------------------------------------*/

Read_Config: procedure expose system.

    dummy.count=0
    MM_ReadStem system.configfile 'dummy'
    if dummy.count=0 then ByeBye('200,;***Error: Config file not found !')

    do x=0 to dummy.count-1
        parse var dummy.x pre '#' keyword ' ' inhalt
        if (pre='') & (keyword~='') then do
            select
                when (keyword='SERVERNAME')         then system.servername          = inhalt
                when (keyword='SYSOPNAME')          then system.sysopname           = inhalt
                when (keyword='UUENCODE')           then system.uuencode            = inhalt
                when (keyword='TEMPFILE')           then system.tempfile            = inhalt
                when (keyword='INDEXFILE')          then system.indexfile           = inhalt
                when (keyword='PASSWDFILE')         then system.passwdfile          = inhalt

                when (keyword='TEXT_HELPFILE')      then system.text.helpfile       = inhalt
                when (keyword='TEXT_FILENOTFOUND')  then system.text.filenotfound   = inhalt
                when (keyword='TEXT_WRONGPASS')     then system.text.wrongpass      = inhalt
                when (keyword='TEXT_FILELIST')      then system.text.filelist       = inhalt
                when (keyword='TEXT_SENDREADME')    then system.text.sendreadme     = inhalt
                when (keyword='TEXT_SENDFILE')      then system.text.sendfile       = inhalt
                when (keyword='TEXT_SENDTEXT')      then system.text.sendtext       = inhalt
                when (keyword='TEXT_SENDSCAN')      then system.text.search         = inhalt
                when (keyword='TEXT_SENDHOLD')      then system.text.hold           = inhalt

                when (keyword='SUBJ_HELPFILE')      then system.subj.helpfile       = inhalt
                when (keyword='SUBJ_FILENOTFOUND')  then system.subj.filenotfound   = inhalt
                when (keyword='SUBJ_WRONGPASS')     then system.subj.wrongpass      = inhalt
                when (keyword='SUBJ_FILELIST')      then system.subj.filelist       = inhalt
                when (keyword='SUBJ_SENDREADME')    then system.subj.sendreadme     = inhalt
                when (keyword='SUBJ_SENDFILE')      then system.subj.sendfile       = inhalt
                when (keyword='SUBJ_SENDTEXT')      then system.subj.sendtext       = inhalt
                when (keyword='SUBJ_SENDSCAN')      then system.subj.search         = inhalt
                when (keyword='SUBJ_SENDHOLD')      then system.subj.hold           = inhalt

                when (keyword='SEARCHFLAGS')        then system.cfg.sflags          = inhalt
                when (keyword='STDFLAGS')           then system.cfg.flags           = inhalt
                when (keyword='STDLEVEL')           then system.cfg.stdlevel        = inhalt
                when (keyword='HOLDLEVEL')          then system.cfg.holdlevel       = inhalt
                when (keyword='DONEFLAGS')          then system.cfg.doneflags       = inhalt
                when (keyword='MAXTXTSIZE')         then system.cfg.txtmaxsize      = inhalt
                when (keyword='MAXFILESIZE')        then system.cfg.binmaxsize      = inhalt
                otherwise nope
            end
        end
    end
return





/* End of file.
============================================================================*/